2-3

$ \DeclareMathOperator{\abs}{abs} \newcommand{\ensuremath}[1]{\mbox{$#1$}} $

図形と方程式(Figure and Equation)

1 点と直線

この範囲は，ベクトルを学習した後にもう一回やるといいと思う。

答だけ知りたければ，グラフィックビューでOK。
分数とかもあるので，答の標準的な求め方はCASで。
\[例題１　直線　x+2y-10=0に関して，点A(1,2)と対称な点の座標を求めよ。\]

Geogebraには対称点（鏡映refrection）があるので，実に楽。
ベクトル利用の計算方法を書いておこう。

直線の法線ベクトル(1,2)を自分の大きさで割って，直線までの距離の2倍進む。
\[例題２　2直線　x+y-4=0,2x-y+1=0について，交点の座標を求め，\\この2直線と直線　mx-y+2m+1=0が1点で交わるような定数m の値を求めよ。\]

グラフィックビューのmとCASのmが同じ文字が使えないのが，注意。

2 円

\[例題１　3点(-7,5),(-3,7),(0,-2)を通る円の方程式を求めよ。\]

\[例題２　直線　y=2x+kが円　x^2+y^2=1と共有点をもつように，定数kの値の範囲を定めよ。\]

\[例題３　点(15,5)を通り，円　x^2+y^2=50に接する直線の方程式を求めよ。\]

3 軌跡と領域

\[例題１　2点A(0,2),B(4,0)から等距離にある点の軌跡を求めよ。\]

計算も，２方法で。「2点からの距離が等しい」と垂直2等分線をベクトル的に解釈して。
答が微妙に違うのがおかしい。

さらにもう一つの方法。
Pを勝手な点として，PAとPBのラベルfとgを使って
LocusEquation(f==g,P)で2x-y=3を出してくれます。

\[例題２　2点A(-6,0),B(2,0)に対して，AP:BP=3:1であるような点の軌跡を求めよ。\]

いわゆるアポロニウスの円。
計算も，２方法で。「2点からの距離の比（k）が一定」と「内分点と外分点を直系の両端とする円」。
グラフィックビューでは，作図させている。
Intersect((x - x(A))² + (y - y(A))² = (k r)², (x - x(B))² + (y - y(B))² = r²)
これはマクロを置いておこう。

さらにもう一つの方法。
Pを勝手な点として，PAとPBのラベルfとgを使って
LocusEquation(f==3g,P)でx^2-6x+y^2=0を出してくれます。すごいね。

\[例題1　不等式　(x-y)(x+y-1)>0の表す領域を図示せよ。\\ 例題2　連立不等式　x+2y\le 4,x-y\le 1,x\ge 0,y\ge 0の表す領域Dを図示し，\\ 点(x,y)がこの領域を動くとき，2x+yの最大値と最小値を求めよ。\] Geogebraは領域も不等式を書くだけ，連立も&&でつなげるだけでOK。

いわゆる線形計画法。等高線を引いている（高い方がy切片が大きい）。
2変数関数の最大値最小値ととらえると，3次元空間で見える。

図形と方程式(Figure and Equation)

1 点と直線

この範囲はベクトルを学習してから，もう一回やるといいといつも思います。
まあ，それはそれとして，関数をどっさり作りました。
symP(a,b,c,d)：(a,b)を中心にした(c,d)の点対称
symL(a,b,c,d,e)：ax+by+c=0 を中心にした(d,e)の線対称
l1(a,b,m)：(a,b)と通る傾きmの直線
l2(a,b,c,d)：(a,b),(c,d)を通る直線
com(a,b,c,d,e,f)：ax+by+c=0とdx+ey+f=0との交点
g(a,b,c,d,e,f)：(a,b),(c,d),(e,f)の重心
m(a,b,c,d)：(a,b),(c,d)の中点
d(a,b,c,d)：(a,b),(c,d)の距離
p(a,b,c,d,m,n)：(a,b),(c,d)をm:nに分ける点の座標
dl(a,b,c,d,e)：ax+by+c=0と(d,e)との距離

(%i1)

symP(a,b,c,d):=[2*a-c,2*b-d]$

(%i2)

symL(a,b,c,d,e):=solve([-a/b*(y-e)/(x-d)+1,a*(x+d)/2+b*(y+e)/2+c],[x,y])$

(%i3)

m(a,b,c,d):=[(a+c)/2,(b+d)/2]$

(%i4)

l1(a,b,m):=ratsimp(expand(m*(x-a)-y+b=0))$

(%i5)

l2(a,b,c,d):=ratsimp(expand(y-b-(d-b)*(x-a)/(c-a)=0))$

(%i6)

com(a,b,c,d,e,f):=solve([a*x+b*y+c,d*x+e*y+f],[x,y])$

(%i7)

d(a,b,c,d):=sqrt((a-c)^2+(b-d)^2)$

(%i8)

dl(a,b,c,d,e):=abs(a*d+b*e+c)/sqrt(a^2+b^2)$

\[例題１　直線　x+2y-10=0に関して，点A(1,2)と対称な点の座標を求めよ。\]

(%i9)

symL(1,2,-10,1,2);

\[(\%o9)[[x=3,y=6]]\] \[例題２　2直線　x+y-4=0,2x-y+1=0について，交点の座標を求め，\\
この2直線と直線　mx-y+2m+1=0が1点で交わるような定数m の値を求めよ。\]
sublis([a],f)というのはリストaをfに代入するという意味

(%i10)

com(1,1,-4,2,-1,1);

\[(\%o10)[[x=1,y=3]]\]

(%i11)

solve(sublis(%[1],m*x-y+2*m+1),m);

\[(\%o11)[m=\frac{2}{3}]\]

2 円

関数をどんどん作ります。
cir(a,b,r)：中心(a,b)半径rの円の方程式
std(l,m,n)：x^2+y^2+lx+my+n=0なる円の一般形から中心と半径を求める
cir3(a,b,c,d,e,f)：3点(a,b),(c,d),(e,f)を通る円の方程式
com2(a,b,c,l,m,n)：直線ax+by+c=0と円x^2+y^2+lx+my+n=0の交点
com3(a,b,R)：(a,b)を通る円x^2+y^2=Rの接線の接点

(%i12)

cir(a,b,r):=(x-a)^2+(y-b)^2=r^2$

(%i13)

std(l,m,n):=[-l/2,-m/2,sqrt((1^2+m^2)/4-n)]$

(%i14)

cir3(a,b,c,d,e,f):=block(
h:x^2+y^2+l*x+m*y+n=0,
c1:sublis([x=a,y=b],h),
c2:sublis([x=c,y=d],h),
c3:sublis([x=e,y=f],h),
sublis(solve([c1,c2,c3],[l,m,n])[1],h)
)$

(%i15)

com2(a,b,c,l,m,n):=solve([a*x+b*y+c=0,x^2+y^2+l*x+m*y+n=0],[x,y])$

(%i16)

com3(a,b,R):=solve([x^2+y^2=R,a*x+b*y=R],[x,y])$

\[例題１　3点(-7,5),(-3,7),(0,-2)を通る円の方程式を求めよ。\\
例題２　直線　y=2x+kが円　x^2+y^2=1と共有点をもつように，定数kの値の範囲を定めよ。\\
例題３　点(15,5)を通り，円　x^2+y^2=50に接する直線の方程式を求めよ。\]

(%i17)

cir3(-7,5,-3,7,0,-2);

\[(\%o17){{y}^{2}}-4y+{{x}^{2}}+6x-12=0\]

(%i18)

com2(2,-1,k,0,0,-1);

\[(\%o18)[[x=-\frac{\sqrt{5-{{k}^{2}}}+2k}{5},y=-\frac{2\sqrt{5-{{k}^{2}}}-k}{5}],[x=\frac{\sqrt{5-{{k}^{2}}}-2k}{5},y=\frac{2\sqrt{5-{{k}^{2}}}+k}{5}]]\]

(%i19)

com3(15,5,50);

\[(\%o19)[[x=5,y=-5],[x=1,y=7]]\]

(%i21)

l2(5,-5,15,5);l2(1,7,15,5);

\[(\%o20)y-x+10=0\] \[(\%o21)\frac{7y+x-50}{7}=0\]

3 軌跡と領域

\[例題１　2点A(0,2),B(4,0)から等距離にある点の軌跡を求めよ。\\
例題２　2点A(-6,0),B(2,0)に対して，AP:BP=3:1であるような点の軌跡を求めよ。\]

(%i22)

d(x,y,0,2)^2-d(x,y,4,0)^2=0;

\[(\%o22)-{{y}^{2}}+{{\left( y-2\right) }^{2}}+{{x}^{2}}-{{\left( x-4\right) }^{2}}=0\]

(%i23)

expand(%);

\[(\%o23)-4y+8x-12=0\]

(%i24)

factor(%);

\[(\%o24)-4\left( y-2x+3\right) =0\]

(%i25)

3^2*(d(x,y,2,0)^2)-d(x,y,-6,0)^2=0;

\[(\%o25)9\left( {{y}^{2}}+{{\left( x-2\right) }^{2}}\right) -{{y}^{2}}-{{\left( x+6\right) }^{2}}=0\]

(%i26)

factor(expand(%));

\[(\%o26)8\left( {{y}^{2}}+{{x}^{2}}-6x\right) =0\]

　　\[例題1　不等式　(x-y)(x+y-1)>0の表す領域を図示せよ。\\
例題2　連立不等式　x+2y\le 4,x-y\le 1,x\ge 0,y\ge 0の表す領域Dを図示し，\\
点(x,y)がこの領域を動くとき，2x+yの最大値と最小値を求めよ。\] Maximaは単体法(Simplex)のパッケージ有り。

(%i27)

load(simplex)$

(%i28)

l:[x+2*y<=4,x-y<=1,x>=0,y>=0]$

(%i29)

minimize_lp(2*x+y,l);

\[(\%o29)[0,[y=0,x=0]]\]

(%i30)

maximize_lp(2*x+y,l);

\[(\%o30)[5,[y=1,x=2]]\]

(%i31)

l:[x+2*y<4,x-y<1]$

(%i32)

maximize_lp(2*x+y,l),nonegative_lp=true;

\[(\%o32)[5,[y=1,x=2]]\]

(%i33)

minimize_lp(2*x+y,l);

\[(\%o33)Problem\,not\,bounded!\] 条件の等号はつけなくてもいいようです。
正の条件は後からつけてもよく，線形なので領域が円だったりするとだめです。

図形と方程式(Figure and Equation)

1 点と直線

分点 dividing point 内分(internal division)，外分(external division)
　ちなみに片方の脚に鉛筆などを差し込むのが compasses ，両脚とも針になっているのが dividers なんだって
中点(midddle point,midpoint)，中線(median line)
中線定理(parallelogram theorem)平行四辺形定理というのか,平行四辺形の対角線を意識してるのだろう
平行(parallel 一致 coincide)，垂直(perpendicular 直交 orthogonal)オーソドックスと同源

2 円

3 軌跡と領域

軌跡：locusラテン語のplaceからというlocalが同源
領域：domain定義域range値域
連立：simultaneous同時に成立する，simulationと同源

Created with wxMaxima.